    var lutdir = getDirectory("startup")+"luts"+File.separator;
    var luts = getLutMenu();
    var lCmds = newMenu("LUT Menu Tool", luts);
    
    macro "LUT Menu Tool - C037T0b10LT6b10UTeb10T" {
         cmd = getArgument();
  	  if (cmd!="-") run(cmd);
    }
    
    function getLutMenu() {
        list = getList("LUTs");
        menu = newArray(3+list.length);
        menu[0] = "Invert LUT";
        menu[1] = "Apply LUT";
        menu[2] = "-";
        for (i=0; i<list.length; i++)
             menu[i+3] = list[i];
        return menu;
    }
